Ccmmutty logo
Commutty IT
・5 min read

esp32でタクトスイッチを使ってみた

電子工作esp32
https://cdn.magicode.io/media/notebox/blob_9ak0Q55

はじめに

前回の記事でesp32でmp3再生を試してみた。
サンプルだと起動後に自動で音が再生されてしまうので、タクトスイッチを押したときに再生するようにしてみた。

環境

前提

前回の記事でmp3の再生環境は整っているとする。

タクトスイッチについて

こちらの記事がわかりやすい。
タクトスイッチは、4つの足が端子として存在するが、同じ側面に2本、反対側の側面に2本という構成になっている。
スイッチを押していないときは、同じ側面の端子同士は接続していないが、スイッチを押すと接続し、電気が通るようになる。
そのため、マイコンのGPIOなどにタクトスイッチの片方の足を接続し、もう片方をVddやGNDにつないでおけば、スイッチを押したときにHigh,Lowにすることができる。
しかしながら、この状態では、スイッチを押していないときは、何にも接続されていない状態となり不安定になってしまい、ノイズに弱くなってしまう。
そこで、プルアップやプルダウンを使うことで、安定させる。
例えば、プルアップでは、
タクトスイッチの片方の足をSW1, もう片方の足をSW2とした場合に、図のように配線する。
この時、スイッチを押していないときは、GPIOはVddにつながり、スイッチを押しているときは、GNDにつながる。
この時の抵抗をプルアップ抵抗と呼び、一般的に10kΩ程度を利用するので、スイッチを押したときには少量の電流が流れるだけで、ショートにはならない。
なお、arudionoやesp32のGPIOにはプルアップ抵抗が内蔵されているので、わざわざ抵抗を用意する必要はない。

タクトスイッチのサンプル

スケッチ例 > esp32 > GPIO > GPIOInterupt でボタンのサンプルが確認できる。
このサンプルでは、
  1. pinModle() の第二引数でINPUT_PULLUPを指定することで、内臓のプルアップ抵抗とつなぐ
  2. attachInterruptArgもしくはattachInterruptでGPIOが建ち下がった時に割り込み処理を呼ぶ ようにしています。
配線して動かせばシリアルモニターで動作確認ができます。

スイッチを押したら再生

記事最後にコードを載せます。
一点、注意事項としては、割り込み内では単純な処理にした方がいい。
例えば、void ARDUINO_ISR_ATTR isr(void* arg) 内でSerial.printf()するとリブートされる。 　
Guru Meditation Error: Core 1 panic'ed (Interrupt wdt timeout on CPU1).
https://stackoverflow.com/a/71992729
割り込み内で変なことしない方がいい模様
#include <Arduino.h>
#if defined(ARDUINO_ARCH_RP2040)
void setup() {}
void loop() {}
#else

#ifdef ESP32
  #include <WiFi.h>
  #include "SPIFFS.h"
#else
  #include <ESP8266WiFi.h>
#endif
#include "AudioFileSourceSPIFFS.h"
#include "AudioGeneratorMP3.h"
#include "AudioOutputI2S.h"

// To run, set your ESP8266 build to 160MHz, and include a SPIFFS of 512KB or greater.
// Use the "Tools->ESP8266/ESP32 Sketch Data Upload" menu to write the MP3 to SPIFFS
// Then upload the sketch normally.  

// pno_cs from https://ccrma.stanford.edu/~jos/pasp/Sound_Examples.html

struct Button {
    const uint8_t PIN;
    const char *filename;
    bool pressed;
};

Button button = {17, "/pno-cs.mp3", false};
void play_audio(const char *);
void stop_audio();

void ARDUINO_ISR_ATTR isr(void* arg) {
    Button* s = static_cast<Button*>(arg);
    s->pressed = true;
}

AudioGeneratorMP3 *mp3;
AudioFileSourceSPIFFS *file;
AudioOutputI2S *out;

void setup()
{
  WiFi.mode(WIFI_OFF); 
  Serial.begin(115200);
  delay(1000);
  SPIFFS.begin();
  Serial.printf("Sample MP3 playback begins...\n");

  // setup audio
  audioLogger = &Serial;
  out = new AudioOutputI2S();
  mp3 = new AudioGeneratorMP3();
  //mp3->begin(id3, out);

  // setup button
  pinMode(button.PIN, INPUT_PULLUP);
  attachInterruptArg(button.PIN, isr, &button, FALLING);
}

void loop()
{
  // check button pressed
  if (button.pressed){
    play_audio(button.filename);
    button.pressed = false;
  }
  
  if (mp3->isRunning()) {
    if (!mp3->loop()) mp3->stop();
  } else {
    Serial.printf("MP3 done\n");
    delay(1000);
  }
}

void play_audio(const char *filename){
  Serial.printf("play audio");
  stop_audio();
  file = new AudioFileSourceSPIFFS(filename);
  mp3->begin(file, out);
}

void stop_audio(){
  if (mp3->isRunning()) {
    mp3->stop(); 
  }
}
#endif

Discussion

コメントにはログインが必要です。